O svakoj naredbi ili opciji koja je u tekstu istaknuta plavom bojom potrazite poblize informacije  u Mathematica HELPU!
Informacije o standardnim Mathematica paketima potrazite u HELPU pod Add-ons.

Naredba Plot

Naredbu  Plot koristimo za crtanje grafa funkcije jedne varijable. Kod crtanja konika ona je pogodna jedino za crtanje parabole kojoj je os paralelna s koordinatnom osi y.

Plot[0.5  x^2 - 3  x - 2, {x, -4, 10}]

Naredba ParametricPlot

Koristimo parametarske jednadzbe krivulja.

Naredbu za crtanje elipse s osima a=8,  b=3 kojoj je srediste u tocki (1,-2) pisemo na sljedeci nacin:

ParametricPlot[{8  Cos[u] + 1, 3  Sin[u] - 2}, {u, 0, 
        2  Pi}]

Naredba ParametricPlot omogucuje crtanje veceg broja krivulja.

ParametricPlot[{{8  Cos[u] + 1, 3  Sin[u] - 2}, {2  Cos[u], 
          2  Sin[u]}}, {u, 0, 2  Pi}]

Uocite sliku kruznice na gornjem crtezu.
Odnos jedinica na koordinatnim osima regulira se opcijom AspectRatio.

ParametricPlot[{{8  Cos[u] + 1, 3  Sin[u] - 2}, {2  Cos[u], 
          2  Sin[u]}}, {u, 0, 2  Pi}, 
      AspectRatio -> Automatic]

Nacrtajmo hiperbolu kojoj je srediste u ishodistu, a realna i imaginarna os duljina a=3 i b=4.

ParametricPlot[{3  Cosh[u], 4  Sinh[u]}, {u, -4, 4}, 
      AspectRatio -> Automatic]

Obje grane te hiperbole crtamo kao dvije parametarski zadane krivulje.

ParametricPlot[{{3  Cosh[u], 4  Sinh[u]}, {-3 Cosh[u], 
          4  Sinh[u]}}, {u, -4, 4}, 
      AspectRatio -> Automatic]

Upotrijebimo li drugu parametrizaciju dobivamo sljedeci prikaz iste hiperbole.

ParametricPlot[{3  Sec[u], 4  Tan[u]}, {u, 0, 2  Pi}, 
      AspectRatio -> Automatic]

Izrez crteza dobivamo koristenjem opcije PlotRange.

ParametricPlot[{3  Sec[u], 4  Tan[u]}, {u, 0, 2  Pi}, 
      AspectRatio -> Automatic, 
      PlotRange -> {{-10, 10}, {-10, 10}}]

Nacrtajmo parabolu kojoj je os paralelna s osi x, tjeme u tocki (1,3), a parametar p=2.

ParametricPlot[{t^2/4 + 1, t + 3}, {t, -6, 6}, 
      AspectRatio -> Automatic]

Naredba ImplicitPlot

Za crtanje koristimo implicitne jednadzbe krivulja. Potrazite u HELPU koja je razlika izmedu znakova "=" i" ==".

Prije ispisivanja naredbe ImplicitPlot mora se ucitati standardni Mathematica paket Graphics`ImplicitPlot`.

Crteze  istih kriulja dobivamo sada na sljedeci nacin:

<< Graphics`ImplicitPlot`

ImplicitPlot[(x - 1)^2/64 + (y + 2)^2/9 == 1, {x, -7, 
        9}]

ImplicitPlot[{(x - 1)^2/64 + (y + 2)^2/9 == 1, 
        x^2/4 + y^2/4 == 1}, {x, -7, 9}]

ImplicitPlot[x^2/9 - y^2/16 == 1, {x, -10, 10}]

ImplicitPlot[(y - 3)^2 == 4 (x - 1), {x, 1, 
        8}]

Naredba PolarPlot

Koristimo polarne jednadzbe krivulja.

Prije ispisivanja naredbe PolarPlot mora se ucitati standardni Mathematica paket Graphics`Graphics`.

<< Graphics`Graphics`

PolarPlot[1.4/(1 - 0.8  Cos[u]), {u, 0, 2  Pi}]

PolarPlot[6  Cos[u], {u, 0, 2  Pi}]

PolarPlot[3, {u, 0, 2  Pi}]

PolarPlot[16/3/(1 - 5/3  Cos[u]), {u, 0, 2  Pi}]

PolarPlot[1.2/(1 - Cos[u]), {u, 0, 2  Pi}, 
      PlotRange -> {{-1, 7}, {-4, 4}}]

Definiranje funkcije

Listu parametarskih jednadzbi elipse odredene poluosima a i b te sredistem (x0,y0) mozemo u Mathematici definirati na sljedeci nacin.

elPar[a_, b_, x0_, y0_][u_] := {a*Cos[u] + x0, 
        b*Sin[u] + y0}

Sada za bilo koji odgovarajuci izbor vrijednosti a, b, x0 i y0 Mathematica racuna parametarske jednadzbe

elPar[5, 3, 1, -2][u]

pa naredbu za crtanje pisemo na sljedeci nacin:

ParametricPlot[elPar[5, 3, 1, -2][u], {u, 0, 2  Pi}]

Kompajliranje funkcije omogucuje naredba Evaluate.

ParametricPlot[elPar[5, 3, 1, -1][u] // Evaluate, {u, 0, 
        2  Pi}]

Bojanje i debljine linija

Standardni paket Graphics`Colors` omogucuje ispisivanje imena boje pri opciji PlotStyle.
Prije ispisivanja naziva boje mora se ucitati standardni Mathematica paket Graphics`Colors`.
Debljine linija odredujemo naredbom AbsoluteThickness u opciji PlotStyle

<< Graphics`Colors`

ParametricPlot[elPar[5, 3, 1, -1][u] // Evaluate, {u, 0, 
        2  Pi}, PlotStyle -> {Red, AbsoluteThickness[2]}]

ParametricPlot[{elPar[5, 3, 1, -2][
            u], elPar[3, 5, -1, 2][u]} // Evaluate, {u, 0, 2  Pi}, 
      PlotStyle -> {{Red, AbsoluteThickness[2]}, {Blue}}, 
      AspectRatio -> Automatic]

Naredba Show

Naredbu Show  mozemo koristiti za prikaze vise razlicitih grafika na istoj slici.

g1 = 
      ImplicitPlot[y == x^2 + 2  x - 1, {x, -4, 2}, 
        PlotStyle -> {Green, AbsoluteThickness[3]}]

g2 = 
      ParametricPlot[{{2  Cos[u], 2  Sin[u] + 5}, {2  Cos[u] + 2, 
            2  Sin[u] + 2}}, {u, 0, 2  Pi}, 
        PlotStyle -> {{Red}, {Yellow, AbsoluteThickness[3]}}]

Show[g1, g2]

Clear[g1, g2]

Naredba Table i animacija

Naredbu Table mozemo koristiti za iscrtavanje veceg broja krivulja na jednom crtezu.......

ParametricPlot[
      Table[elPar[i, 2  i/3, i, 0][u], {i, 1, 10, 1}] // Evaluate, {u, 0, 
        2  Pi}]

........ili za iscrtavanje niza slika koje tvore animaciju. Za dobro funkcioniranje animacije gotovo je obavezno koristiti opciju PlotRange.

Table[
      ParametricPlot[elPar[i, 2  i/3, i, 0][u] // Evaluate, {u, 0, 
          2  Pi}, PlotRange -> {{0, 20}, {-10, 10}}], {i, 1, 10, 
        1}]