Građevinski fakultet Sveučilišta u Zagrebu
Osnove inženjerske informatike II (Mathematica)
8. predavanje

3D grafika

Funkcija Graphics3D - 3DPrimitivi

Funkcija Graphics3D omogućava, između ostalog, crtanje 3D primitiva

•  Sintaksa za crtanje  primitiva je sljedeća:
Graphics3D[ 2Dprimitiv ]

•  Sintaksa  za crtanje više primitiva je sljedeća:
Graphics3D[ { 2Dprimitiv 1, 2Dprimitiv 2,..... } ]

•  Opcije za crtanje dodaju se na sljedeći način:
Graphics3D[ { opcija1,opcija2,....,2Dprimitiv } ]

3D primitivi

Point[{x,y,z}]

Točka s koordinatama (x,y,z).

Line[{{(Subscript[x, 1]),(Subscript[y, 1]),(Subscript[z, 1])},{(Subscript[x, 2]),(Subscript[y, 2]),(Subscript[z, 2])},..}]

Pravac ili više pravaca koji su spojnice točaka  ((Subscript[x, 1]),(Subscript[y, 1])),((Subscript[x, 2]),(Subscript[y, 2])),..

Polygon[{{(Subscript[x, 1]),(Subscript[y, 1]),(Subscript[z, 1])},{(Subscript[x, 2]),(Subscript[y, 2]),(Subscript[z, 2])},{(Subscript[x, 3]),(Subscript[y, 3]),(Subscript[z, 3])},....}]

Prostorni poligon čiji su vrhovi redom točke   ((Subscript[x, 1]),(Subscript[y, 1]),(Subscript[z, 1])),((Subscript[x, 2]),(Subscript[y, 2]),(Subscript[z, 2])),((Subscript[x, 3]),(Subscript[y, 3]),(Subscript[z, 3])),....

Cuboid[{(Subscript[x, 1]),(Subscript[y, 1]),(Subscript[z, 1])}]

Jedinična kocka kojoj je točka  ((Subscript[x, 1]),(Subscript[y, 1]),(Subscript[z, 1])) jedan vrh.

Cuboid[{{(Subscript[x, 1]),(Subscript[y, 1]),(Subscript[z, 1])},{(Subscript[x, 2]),(Subscript[y, 2]),(Subscript[z, 2])}}]

Kvadratska prizma  kojoj je spojnica točaka  ((Subscript[x, 1]),(Subscript[y, 1]),(Subscript[z, 1]))  i  ((Subscript[x, 2]),(Subscript[y, 2]),(Subscript[z, 2])) prostorna dijagonala.

Sphere[{x,y,z},r]

Kugla sa sredistem u točki (x,y,z) i polumjera r.

Cylinder[{{(Subscript[x, 1]),(Subscript[y, 1]),(Subscript[z, 1])},{(Subscript[x, 2]),(Subscript[y, 2]),(Subscript[z, 2])}},r]

Valjak  kojem je spojnica točaka  ((Subscript[x, 1]),(Subscript[y, 1]),(Subscript[z, 1]))  i  ((Subscript[x, 2]),(Subscript[y, 2]),(Subscript[z, 2])) os, a polumjer r.

Text[tekst,{x,y,z}]

Ispisuje tekst koji je centriran u točku (x,y,z).

Primjeri

Graphics3D[
{
Cuboid[{0,2,3}],
Cuboid[{{5,0,0},{4,1,2}}],
Sphere[{3,3,4},1],
Cylinder[{{0,0,0},{1,0,2}},1]
}
]

Uz dodatne opcije

Graphics3D[
{
{Opacity[0.6],EdgeForm[Red],FaceForm[Yellow],Cuboid[{0,2,3}]},
{Orange,Sphere[{3,3,4},1]},
{Opacity[0.8],Green,Cylinder[{{0,0,0},{1,0,2}},1]},
{Black,AbsolutePointSize[8],Point[{1,0,2}]},
{Cyan,Cuboid[{{5,0,0},{4,1,2}}]}
}
]

Prodor dvaju valjaka

Graphics3D[
{
Opacity[0.9],Yellow,Cylinder[{{0,0,0},{0,0,6}},2],
Cyan,Cylinder[{{-3,0,3},{3,0,3}},2]
}
]

Manipulate[
Graphics3D[
{
Opacity[0.9],Yellow,Cylinder[{{0,0,-1},{0,0,7}},2],
Cyan,Cylinder[{{-3,0,3},{3,0,3}},r]
}],

{r,1,4}]

Prodor valjka i kugle

Manipulate[
Graphics3D[
{
Opacity[0.9],Yellow,Sphere[{0,0,0},2],
Cyan,Cylinder[{{x,0,-3},{x,0,3}},1]
}
],

{x,2,0}]

Funkcija Plot3D

Kao što smo već ranije spomenuli, Mathematica naredba koja omogućuje crtanje grafa realne funkcije dviju varijabli f : 𝒰 -> ℝ, 𝒰⊆(ℝ^2),
tj. ploha zadanih eksplicitnim jednadžbama oblika z = f(x,y), je Plot3D.
 Za crtanje jedne plohe sintaksa je
Plot3D [ f , {x,(Subscript[x, min]),(Subscript[x, max])}, {y,(Subscript[y, min]),(Subscript[y, max])} ],
a za crtanje više ploha 
Plot3D [ { (Subscript[f, 1]),(Subscript[f, 2]),...}, {x,(Subscript[x, min]),(Subscript[x, max])}, {y,(Subscript[y, min]),(Subscript[y, max])} ]

Primjer 1

Prikažite plohu zadanu jednadžbom  z = cos(x^( ))cos y  za  (x,y) ∈ (([–3,3])^2)

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3}]

Opcije

Options[Plot3D]

Opcija BoxRatios

?BoxRatios

Opcijom BoxRatios izražava se omjer stranica kocke u koju je ucrtana 3D slika.
BoxRatios-> {1,1,1}          prikazuje grafiku unutar kocke
BoxRatios-> Automatic    duljine osi odgovaraju stvarnim vrijednostima koordinata

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},BoxRatios->Automatic]

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},BoxRatios->{1,1,1}]

Opcije Mesh i MeshStyle

?Mesh

Opcijom Mesh definira se iscrtavanje mreže linija na plohi.

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},Mesh->50]

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},Mesh->{0,50}]

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},Mesh->None]

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},Mesh->All]

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},MeshStyle->White]

Opcija PlotPoints

?PlotPoints

Opcijom PlotPoints definira se "finoća" grafike.

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},PlotPoints->2]

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},PlotPoints->20]

Opcija PlotRange

?PlotRange

Opcijom PlotRange definira dio prostora koji se prikazuje.
Ovu je opciju gotovo neophodno uportebljavati kod animacija.

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},PlotRange->{{-3,3},{-3,3},{-0.5,0.5}}]

Opcija Boxed  i  Axes

?Boxed

?Axes

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},Mesh->{0,30},
Boxed->False,Axes->False]

Opcija AxesLabel

?AxesLabel

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},Mesh->{0,30},
Boxed->False,AxesLabel->{x,y,z}]

Opcija PlotStyle

?PlotStyle

Pomoću ove opcije definiramo razne načine crtanja (boju, prozirnost, debljinu linija......), od kojih neke ovdje navodimo.

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},PlotStyle->Yellow]

Opcija Opacity

?Opacity

Opcijom Opacity definiramo prozirnost prikaza. Prozirnost određujemo brojem od 0 do 1, pri čemu 1 znači neprozirno.
Kod crtanja ploha uvijek ju pozivamo pomoću opcije PlotStyle.

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},PlotStyle->Opacity[0.7]]

Možemo joj pridodati i boju.

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},PlotStyle->Opacity[0.7,Green]]

Plot3D[{Cos[x]*Cos[y],Sin[x]*Cos[y]},{x,-2Pi,2Pi},{y,-2Pi,2Pi},Mesh->10,PlotStyle->{Opacity[0.9,Yellow],Opacity[0.7,Green]},PlotPoints->30]

Opcija ColorFunction

?ColorFunction

Opcijom ColorFunction određujemo koju će od svojih ugrađenih kolor funkcija Mathematika upotrijebiti za grafiku. 
Lista tih funkcija nalazi se u paletama.

Plot3D[Cos[x]*Cos[y],{x,-3,3},{y,-3,3},Mesh->None,ColorFunction->"BrightBands"]

Primjer 2 - majmunsko sedlo

z = (x^(3 ))– 3((xy)^2)

Plot3D[x^3-3x*y^2,{x,-1,1},{y,-1,1},BoxRatios->{1,1,1}]

Manipulate[
Plot3D[x^3-3i*x*y^2,{x,-1,1},{y,-1,1}],
{i,-0.6,1.2,0.05}]

Manipulate[
Plot3D[x^3-3i*x*y^2,{x,-1,1},{y,-1,1},

BoxRatios->{1,1,1},
PlotRange->{{-1,1},{-1,1},{-3,3}},
Mesh->False,
Boxed->False,Axes->False,
PlotPoints->50,
Background->Gray,ColorFunction->"GreenPinkTones"],
{i,-0.6,1.2,0.05}]

Funkcija ParametricPlot3D

1. Prostorne krivulje

Parametarizacija prostorne krivulje

Mathematica funkcija koja omogućuje crtanje parametarski zadanih prostornih krivulja je ParametricPlot3D.
Za crtanje prostorne krivulje zadane parametarskim jednadžbama
(Subscript[f, x]) = x(t)
 (Subscript[f, y]) = y(t)
 (Subscript[f, z]) = z(t),  t ϵ I ⊆ ℜ
 sintaksa je sljedeća:
ParametricPlot3D[{(Subscript[f, x]),(Subscript[f, y]),(Subscript[f, z])}, {t,(Subscript[t, min]),(Subscript[t, max])}] 
Za crtanje više parametarski zadanih krivulja na istom crtežu sintaksa je sljedeća:
ParametricPlot3D[{{(Subscript[f, x]),(Subscript[f, y]),(Subscript[f, z])},{(Subscript[g, x]),(Subscript[g, y]),(Subscript[g, z])},.....}, {t,(Subscript[t, min]),(Subscript[t, max])}]

Primjer — zavojnica na valjku

Parametarske jednadžbe zavojnice na rotacijskom valjku kojem je os paralelna s osi z, a polumjer osnovice jednak r, su:
x = r·cost
y = r·sint
z = b·t,  t ∈ I ⊆ ℝ.

ParametricPlot3D[{4Cos[t],4Sin[t],t},{t,0,5Pi}]

g1=ParametricPlot3D[{4Cos[t],4Sin[t],t},{t,0,5Pi},PlotStyle->{Blue,AbsoluteThickness[2]}]

ParametricPlot3D[
{{4Cos[2t],4Sin[2t],t},
{3Cos[t],3Sin[t],t},
{2Cos[t-2],2Sin[t-2],t}},
{t,0,5Pi}]

2. Plohe

Parametarizacija plohe

Mathematica funkcija koja omogućuje crtanje parametarski zadanih ploha je ParametricPlot3D.
Za crtanje plohe zadane parametarskim jednadžbama
(Subscript[f, x]) = x(u,v)
 (Subscript[f, y]) = y(u,v)
 (Subscript[f, z]) = z(u,v),    (u,v) ϵ 𝒰 ⊂ (ℜ^2)
 sintaksa je sljedeća:
ParametricPlot3D[{(Subscript[f, x]),(Subscript[f, y]),(Subscript[f, z])}, {u,(Subscript[u, min]),(Subscript[u, max])},{v,(Subscript[v, min]),(Subscript[v, max])}] 
Za crtanje više parametarski zadanih ploha na istom crtežu sintaksa je sljedeća:
ParametricPlot3D[{{(Subscript[f, x]),(Subscript[f, y]),(Subscript[f, z])},{(Subscript[g, x]),(Subscript[g, y]),(Subscript[g, z])},.....}, {u,(Subscript[u, min]),(Subscript[u, max])},{v,(Subscript[v, min]),(Subscript[v, max])}]

Primjeri 1 — kugla i elipsoid

Parametarske jednadžbe kugle polumjera R, sa  središtem u točki (p,q,r) su:
	x = R·cosu·sinv + p
	y = R·sinu·sinv + q
	z = R·cosv + r,             (u,v) ∈ [0 , 2π] × [0 , π].
Parametarske jednadžbe troosnog elipsoida  sa  središtem u točki (p,q,r) su:
	x = a·cosu·sinv + p
	y = b·sinu·sinv + q
	z = c·cosv + r,             (u,v) ∈ [0 , 2π] × [0 , π].

Stoga je naredba za crtanje jedinične kugle sa središtem u ishodištu sljedeća:

k=ParametricPlot3D[{Cos[u]*Sin[v],Sin[u]*Sin[v],Cos[v]},{u,0,2Pi},{v,0,Pi}]

ParametricPlot3D[{Cos[u]*Sin[v],Sin[u]*Sin[v],Cos[v]},{u,0,2Pi},{v,0,Pi},Mesh->{20,0}]

ParametricPlot3D[{Cos[u]*Sin[v],Sin[u]*Sin[v],Cos[v]},{u,0,2Pi},{v,0,Pi},Mesh->{0,20},PlotPoints->30]

kugla[R_]:={R*Cos[u] Sin[v],R *Sin[u] Sin[v],R*Cos[v]}

Manipulate[
ParametricPlot3D[kugla[1],{u,0,uu},{v,0,vv},PlotRange->{{-1,1},{-1,1},{-1,1}}],

{{uu,Pi},0.01,2Pi},
{{vv,Pi/2},0.01,Pi}]

ParametricPlot3D[{{3 Cos[u] Sin[v],2 Sin[u] Sin[v],Cos[v]},{2 Cos[u] Sin[v],2 Sin[u] Sin[v],2 Cos[v]+3}},{u,0,((3 π)/2)},{v,0,π},
PlotStyle->{Red,Green}]

ParametricPlot3D[Table[kugla[R],{R,1,4,1}]//Evaluate,{u,0,((3 π)/2)},{v,0,π},
PlotStyle->Table[{Hue[2/R^2]},{R,1,4,1}]//Evaluate]

Primjer 2  — kružni valjak

g2=ParametricPlot3D[{4Cos[u],4Sin[u],z},{u,0,2Pi},{z,0,16},Mesh->None,PlotStyle->{Opacity[0.7,Yellow]}]

Show[g2,g1]

Primjeri 3 — torus

Torus je ploha koja nastaje rotacijom kružnice polumjera a oko osi koja je od središta te kružnice udaljena za d.
Ako kružnica leži u ravnini xz i rotira oko osi z, parametarske jednadžbe torusa su:
	x = cosu (d + a·cosv )
	y = sinu (d + a·cosv )
	z = a·sinv,             (u,v) ∈ [0 , 2π] × [0 ,2 π].

torus[a_,d_]:={Cos[u](d+a*Cos[v]),Sin[u](d+a*Cos[v]),a*Sin[v]}

Stoga je naredba za crtanje jedinične kugle sa središtem u ishodištu sljedeća:

ParametricPlot3D[torus[2,3],{u,0,2Pi},{v,0,2Pi}]

ParametricPlot3D[torus[3,3],{u,0,2Pi},{v,0,2Pi},PlotStyle->Opacity[0.7],Mesh->{20,0}]

ParametricPlot3D[torus[4,3],{u,0,2Pi},{v,0,2Pi},PlotStyle->Opacity[0.7],Mesh->{20,0}]

Manipulate[
Show[ParametricPlot3D[torus[a,d], {u, 0, uu}, {v, 0, 2*Pi}, 
Mesh -> mm, PlotStyle->pp,
PlotRange -> {{-9,9}, {-9,9}, {-4.5, 4.5}}],
ParametricPlot3D[{Cos[uu](a*Cos[v]+d),Sin[uu](a*Cos[v]+d),a*Sin[v]},{v,0,2Pi},PlotStyle->{Red,AbsoluteThickness[2]}],
Graphics3D[{Hue[1],Line[{{0,0,4.5},{0,0,-4.5}}]}]],

	{{mm,{Floor[uu],0},"Mesh: "},{{20,0},{0,20},None,Automatic}},
         {{pp,Opacity[1],"Opacity: "},{Opacity[1],Opacity[0.7]}},
	{{a, 2}, 1, 9/2,Appearance-> "Labeled"},
{{d, 3}, 0, 9/2,Appearance-> "Labeled"},
	{{uu, Pi/72}, Pi/72, 2*Pi,Appearance-> "Labeled"}
]

Primjer 4 — Steinerova ploha

Steinerova ploha je algebarska ploha 4. reda s 4 dvostruka pravca, koja se može parametrizirati na sljedeći način:
	x = sin2u ·(cos^2)v
	y = sinu sin2v
	z = cosu sin2v,             (u,v) ∈ [0 , π] × [0 , π].

SteinerovaPloha={Sin[2u] Cos[v]^2,Sin[u] Sin[2v],Cos[u] Sin[2v]};

ParametricPlot3D[SteinerovaPloha,{u,0,Pi},{v,0,Pi}]

ParametricPlot3D[SteinerovaPloha,{u,0,Pi},{v,0,Pi},Mesh->None,PlotPoints->33,Axes->None,Boxed->False,PlotStyle->{Specularity[White,10],Brown,Opacity[0.8]}]

Funkcija ContourPlot3D

Funkcije ContourPlot3D omogućuju crtanje  nivo-ploha za funkcije od  tri varijable.
U okviru ovog kolegija mi ćemo ju koriprostornom Kartezijevom koordinatnom sustavu zadane implicitnim jednadžbama, tj. jednadžbama oblika:
f(x,y,z)=0.
Sintaksa je sljedeća:
ContourPlot3D[ jednadžba , {x,(Subscript[x, min]),(Subscript[x, max])},{y,(Subscript[y, min]),(Subscript[y, max])},{z,(Subscript[z, min]),(Subscript[z, max])}]
ContourPlot3D[ {(Subscript[jednadžba,   1]),(Subscript[jednadžba,   2]),.......}, {x,(Subscript[x, min]),(Subscript[x, max])},{y,(Subscript[y, min]),(Subscript[y, max])},{z,(Subscript[z, min]),(Subscript[z, max])}]
Kod ove funkcije Mathematica će kao temeljnu opciju za prikaz uzimati BoxRatios -> {1,1,1}, tj. plohu će prikazivati unutar kocke. Želimo li da jedinice na osima budu jednake proporcije, a to nam je često potrebno, treba dopisatii  opciju  BoxRatios -> Automatic.

Primjer 1

ALGEBARSKE PLOHE 2. STUPNJA

KUGLA

ContourPlot3D[x^2+y^2+z^2==1,
{x,-1,1},{y,-1,1},{z,-1,1}]

ContourPlot3D[x^2+y^2+z^2==1,{x,-1,1},{y,-1,1},{z,-1,1}, ContourStyle->Opacity[0.7,Cyan],
Mesh->{0,0,15}]

ContourPlot3D[x^2+y^2+z^2==1,{x,-1,1},{y,-1,1},{z,-1,1}, ContourStyle->{Specularity[White,20],Cyan},
Mesh->None]

ContourPlot3D[x^2+y^2+z^2==1,{x,-1,1},{y,-1,1},{z,-1,1}, ContourStyle->{Specularity[White,10],Hue[0.7,0.2,0.4]},
Mesh->None]

ELIPSOID

ContourPlot3D[x^2/4+y^2/9+z^2/16==1,
{x,-2,2},{y,-3,3},{z,-4,4},
BoxRatios->Automatic,AxesLabel->{x,y,z}]

JEDNODIJELNI HIPERBOLOID

ContourPlot3D[x^2+y^2-z^2==1,
{x,-3,3},{y,-3,3},{z,-2,2},
BoxRatios->Automatic,AxesLabel->{x,y,z}]

DVODIJELNI HIPERBOLOID

ContourPlot3D[x^2-y^2-z^2==1,
{x,-3,3},{y,-3,3},{z,-3,3},
BoxRatios->Automatic,AxesLabel->{x,y,z}]

PARABOLOID

ContourPlot3D[x^2+y^2-z==1,
{x,-3,3},{y,-3,3},{z,-1,4},
BoxRatios->Automatic,AxesLabel->{x,y,z}]

HIPERBOLIČKI PARABOLOID

ContourPlot3D[x^2-y^2-z==0,
{x,-1,1},{y,-1,1},{z,-1,1},
BoxRatios->Automatic,AxesLabel->{x,y,z}]

STOŽAC

ContourPlot3D[x^2+y^2-z^2==0,
{x,-1,1},{y,-1,1},{z,-1,1},
BoxRatios->Automatic,AxesLabel->{x,y,z}]

VALJAK

ContourPlot3D[x^2+y^2==1,
{x,-1,1},{y,-1,1},{z,-2,2},
BoxRatios->Automatic,AxesLabel->{x,y,z}]

Primjer 2

Algebarska ploha 3. reda zadana je jednadžbom:
 16 (x^3)-48 y (x^2)+24 z (x^2)-48 (y^2) x+16 (y^3)-31 (z^3)-93.5307 (z^2)+24 (y^2) z-72 z=0
Prikažite ju za  (x,y,z) ∈ (([–5,4])^(  ))×(([–5,4])^(  ))×(([–4,7])^(  )).

ploha2=16 (x^3)-48 y (x^2)+24 z (x^2)-48 (y^2) x+16 (y^3)-31 (z^3)-93.5307 (z^2)+24 (y^2) z-72 z;

ContourPlot3D[ploha2==0,{x,-5,4},{y,-5,4},{z,-4,7}]

ContourPlot3D[ploha2==0,{x,-5,4},{y,-5,4},{z,-4,7},Mesh->None,PlotPoints->33,AxesLabel->{x,y,z},ContourStyle->{Specularity[White,10],Pink}]

Primjer 3

Algebarska ploha 4. reda s 8 dvostrukih točaka zadana je jednadžbom:
 (x^4)-(x^2)+(y^4)+(z^4)-(y^2)-(z^2)+0.5=0
Prikažite ju za  (x,y,z) ∈ (([–1,1])^(  3)).

ploha3=(x^4)-(x^2)+(y^4)+(z^4)-(y^2)-(z^2)+0.5;

ContourPlot3D[ploha3==0,{x,-1,1},{y,-1,1},{z,-1,1}]

ContourPlot3D[ploha3==0,{x,-1,1},{y,-1,1},{z,-1,1},
PlotPoints->33,
ContourStyle->{Specularity[White,20],Orange},
Mesh->None,
Lighting->{{White,ImageScaled[{1,1,1}]},
{White,ImageScaled[{-1,-1,-1}]}}]

Funkcija RegionPlot3D

Za grafički prikaz rješenja nejednadžbi od 3 varijable koristimo funkciju   RegionPlot3D.
Sintaksa je sljedeća:
RegionPlot3D[ izraz, {x,(Subscript[x, min]),(Subscript[x, max])},{y,(Subscript[y, min]),(Subscript[y, max])},{z,(Subscript[z, min]),(Subscript[z, max])}]
Mathematica  prikazuje dio prostora unutar kvadra ((Subscript[x, min]),(Subscript[x, max]))×((Subscript[y, min]),(Subscript[y, max]))×((Subscript[z, min]),(Subscript[z, max])) za koji vrijedi izraz.
izraz može biti bilo koja nejednadžba od tri varijable (x, y i z) ili logička kombinacija takvih nejednadžbi.

Primjeri

RegionPlot3D[
x^2+y^2+z^2<1&&x^2+y^2+z^2>1/4,
{x,-1,1},{y,-1,1},{z,-1,0},Mesh->None,BoxRatios->Automatic]

ContourPlot3D[
x y z==-1,{x,-5,5},{y,-5,5},{z,-5,5},
Mesh->None]

RegionPlot3D[
x y z<-1,
{x,-5,5},{y,-5,5},{z,-5,5},
Mesh->None]

RegionPlot3D[
x y z>-1,
{x,-5,5},{y,-5,5},{z,-5,5},
Mesh->None,
PlotStyle->Opacity[0.6]]

RegionPlot3D[x y z>-1,{x,-5,5},{y,-5,5},{z,-5,5},
Mesh->8,PlotPoints->43,
MeshFunctions->{Function[{x,y,z},Norm[{x,y,z}]]},
MeshShading->{Directive[Yellow,Opacity[0.4]],FaceForm[Cyan,Red]}]

RegionPlot3D[x y z>-1,{x,-5,5},{y,-5,5},{z,-5,5},
Mesh->20,PlotPoints->43,
MeshFunctions->{Function[{x,y,z},Norm[{x,y,z}]]},ColorFunction->"GreenBrownTerrain"]

Notebook izradili: Sonja Gorjanc, Vladimir Benić